RFC 8941 - Structured Field Values for HTTP

This document describes a set of data types and associated algorithms that are intended to make it easier and safer to define and handle HTTP header and trailer fields, known as "Structured Fields", "Structured Headers", or "Structured Trailers". It is intended for use by specifications of new HTTP fields that wish to use a common syntax that is more restrictive than traditional HTTP field values.¶

3. Structured Data Types

This section defines the abstract types for Structured Fields. The ABNF provided represents the on-wire format in HTTP field values.¶

In summary:¶

There are three top-level types that an HTTP field can be defined as: Lists, Dictionaries, and Items.
Lists and Dictionaries are containers; their members can be Items or Inner Lists (which are themselves arrays of Items).
Both Items and Inner Lists can be Parameterized with key/value pairs.

3.1. Lists

Lists are arrays of zero or more members, each of which can be an Item (Section 3.3) or an Inner List (Section 3.1.1), both of which can be Parameterized (Section 3.1.2).¶

The ABNF for Lists in HTTP fields is:¶

sf-list       = list-member *( OWS "," OWS list-member )
list-member   = sf-item / inner-list

Each member is separated by a comma and optional whitespace. For example, a field whose value is defined as a List of Tokens could look like:¶

Example-List: sugar, tea, rum

An empty List is denoted by not serializing the field at all. This implies that fields defined as Lists have a default empty value.¶

Note that Lists can have their members split across multiple lines of the same header or trailer section, as per Section 3.2.2 of [RFC7230]; for example, the following are equivalent:¶

Example-List: sugar, tea, rum

and¶

Example-List: sugar, tea
Example-List: rum

However, individual members of a List cannot be safely split between lines; see Section 4.2 for details.¶

Parsers MUST support Lists containing at least 1024 members. Field specifications can constrain the types and cardinality of individual List values as they require.¶

3.1.1. Inner Lists

An Inner List is an array of zero or more Items (Section 3.3). Both the individual Items and the Inner List itself can be Parameterized (Section 3.1.2).¶

The ABNF for Inner Lists is:¶

inner-list    = "(" *SP [ sf-item *( 1*SP sf-item ) *SP ] ")"
                parameters

Inner Lists are denoted by surrounding parenthesis, and their values are delimited by one or more spaces. A field whose value is defined as a List of Inner Lists of Strings could look like:¶

Example-List: ("foo" "bar"), ("baz"), ("bat" "one"), ()

Note that the last member in this example is an empty Inner List.¶

A header field whose value is defined as a List of Inner Lists with Parameters at both levels could look like:¶

Example-List: ("foo"; a=1;b=2);lvl=5, ("bar" "baz");lvl=1

Parsers MUST support Inner Lists containing at least 256 members. Field specifications can constrain the types and cardinality of individual Inner List members as they require.¶

3.1.2. Parameters

Parameters are an ordered map of key-value pairs that are associated with an Item (Section 3.3) or Inner List (Section 3.1.1). The keys are unique within the scope of the Parameters they occur within, and the values are bare items (i.e., they themselves cannot be parameterized; see Section 3.3).¶

Implementations MUST provide access to Parameters both by index and by key. Specifications MAY use either means of accessing them.¶

The ABNF for Parameters is:¶

parameters    = *( ";" *SP parameter )
parameter     = param-key [ "=" param-value ]
param-key     = key
key           = ( lcalpha / "*" )
                *( lcalpha / DIGIT / "_" / "-" / "." / "*" )
lcalpha       = %x61-7A ; a-z
param-value   = bare-item

Note that parameters are ordered as serialized, and parameter keys cannot contain uppercase letters. A parameter is separated from its Item or Inner List and other parameters by a semicolon. For example:¶

Example-List: abc;a=1;b=2; cde_456, (ghi;jk=4 l);q="9";r=w

Parameters whose value is Boolean (see Section 3.3.6) true MUST omit that value when serialized. For example, the "a" parameter here is true, while the "b" parameter is false:¶

Example-Integer: 1; a; b=?0

Note that this requirement is only on serialization; parsers are still required to correctly handle the true value when it appears in a parameter.¶

Parsers MUST support at least 256 parameters on an Item or Inner List, and support parameter keys with at least 64 characters. Field specifications can constrain the order of individual parameters, as well as their values' types as required.¶

3.2. Dictionaries

Dictionaries are ordered maps of key-value pairs, where the keys are short textual strings and the values are Items (Section 3.3) or arrays of Items, both of which can be Parameterized (Section 3.1.2). There can be zero or more members, and their keys are unique in the scope of the Dictionary they occur within.¶

Implementations MUST provide access to Dictionaries both by index and by key. Specifications MAY use either means of accessing the members.¶

The ABNF for Dictionaries is:¶

sf-dictionary  = dict-member *( OWS "," OWS dict-member )
dict-member    = member-key ( parameters / ( "=" member-value ))
member-key     = key
member-value   = sf-item / inner-list

Members are ordered as serialized and separated by a comma with optional whitespace. Member keys cannot contain uppercase characters. Keys and values are separated by "=" (without whitespace). For example:¶

Example-Dict: en="Applepie", da=:w4ZibGV0w6ZydGU=:

Note that in this example, the final "=" is due to the inclusion of a Byte Sequence; see Section 3.3.5.¶

Members whose value is Boolean (see Section 3.3.6) true MUST omit that value when serialized. For example, here both "b" and "c" are true:¶

Example-Dict: a=?0, b, c; foo=bar

Note that this requirement is only on serialization; parsers are still required to correctly handle the true Boolean value when it appears in Dictionary values.¶

A Dictionary with a member whose value is an Inner List of Tokens:¶

Example-Dict: rating=1.5, feelings=(joy sadness)

A Dictionary with a mix of Items and Inner Lists, some with parameters:¶

Example-Dict: a=(1 2), b=3, c=4;aa=bb, d=(5 6);valid

As with Lists, an empty Dictionary is represented by omitting the entire field. This implies that fields defined as Dictionaries have a default empty value.¶

Typically, a field specification will define the semantics of Dictionaries by specifying the allowed type(s) for individual members by their keys, as well as whether their presence is required or optional. Recipients MUST ignore members whose keys that are undefined or unknown, unless the field's specification specifically disallows them.¶

Note that Dictionaries can have their members split across multiple lines of the same header or trailer section; for example, the following are equivalent:¶

Example-Dict: foo=1, bar=2

and¶

Example-Dict: foo=1
Example-Dict: bar=2

However, individual members of a Dictionary cannot be safely split between lines; see Section 4.2 for details.¶

Parsers MUST support Dictionaries containing at least 1024 key/value pairs and keys with at least 64 characters. Field specifications can constrain the order of individual Dictionary members, as well as their values' types as required.¶

3.3. Items

An Item can be an Integer (Section 3.3.1), a Decimal (Section 3.3.2), a String (Section 3.3.3), a Token (Section 3.3.4), a Byte Sequence (Section 3.3.5), or a Boolean (Section 3.3.6). It can have associated parameters (Section 3.1.2).¶

The ABNF for Items is:¶

sf-item   = bare-item parameters
bare-item = sf-integer / sf-decimal / sf-string / sf-token
            / sf-binary / sf-boolean

For example, a header field that is defined to be an Item that is an Integer might look like:¶

Example-Integer: 5

or with parameters:¶

Example-Integer: 5; foo=bar

3.3.1. Integers

Integers have a range of -999,999,999,999,999 to 999,999,999,999,999 inclusive (i.e., up to fifteen digits, signed), for IEEE 754 compatibility [IEEE754].¶

The ABNF for Integers is:¶

sf-integer = ["-"] 1*15DIGIT

For example:¶

Example-Integer: 42

Integers larger than 15 digits can be supported in a variety of ways; for example, by using a String (Section 3.3.3), a Byte Sequence (Section 3.3.5), or a parameter on an Integer that acts as a scaling factor.¶

While it is possible to serialize Integers with leading zeros (e.g., "0002", "-01") and signed zero ("-0"), these distinctions may not be preserved by implementations.¶

Note that commas in Integers are used in this section's prose only for readability; they are not valid in the wire format.¶

3.3.2. Decimals

Decimals are numbers with an integer and a fractional component. The integer component has at most 12 digits; the fractional component has at most three digits.¶

The ABNF for decimals is:¶

sf-decimal  = ["-"] 1*12DIGIT "." 1*3DIGIT

For example, a header whose value is defined as a Decimal could look like:¶

Example-Decimal: 4.5

While it is possible to serialize Decimals with leading zeros (e.g., "0002.5", "-01.334"), trailing zeros (e.g., "5.230", "-0.40"), and signed zero (e.g., "-0.0"), these distinctions may not be preserved by implementations.¶

Note that the serialization algorithm (Section 4.1.5) rounds input with more than three digits of precision in the fractional component. If an alternative rounding strategy is desired, this should be specified by the header definition to occur before serialization.¶

3.3.3. Strings

Strings are zero or more printable ASCII [RFC0020] characters (i.e., the range %x20 to %x7E). Note that this excludes tabs, newlines, carriage returns, etc.¶

The ABNF for Strings is:¶

sf-string = DQUOTE *chr DQUOTE
chr       = unescaped / escaped
unescaped = %x20-21 / %x23-5B / %x5D-7E
escaped   = "\" ( DQUOTE / "\" )

Strings are delimited with double quotes, using a backslash ("\") to escape double quotes and backslashes. For example:¶

Example-String: "hello world"

Note that Strings only use DQUOTE as a delimiter; single quotes do not delimit Strings. Furthermore, only DQUOTE and "\" can be escaped; other characters after "\" MUST cause parsing to fail.¶

Unicode is not directly supported in Strings, because it causes a number of interoperability issues, and -- with few exceptions -- field values do not require it.¶

When it is necessary for a field value to convey non-ASCII content, a Byte Sequence (Section 3.3.5) can be specified, along with a character encoding (preferably UTF-8 [STD63]).¶

Parsers MUST support Strings (after any decoding) with at least 1024 characters.¶

3.3.4. Tokens

Tokens are short textual words; their abstract model is identical to their expression in the HTTP field value serialization.¶

The ABNF for Tokens is:¶

sf-token = ( ALPHA / "*" ) *( tchar / ":" / "/" )

For example:¶

Example-Token: foo123/456

Parsers MUST support Tokens with at least 512 characters.¶

Note that Token allows the same characters as the "token" ABNF rule defined in [RFC7230], with the exceptions that the first character is required to be either ALPHA or "*", and ":" and "/" are also allowed in subsequent characters.¶

3.3.5. Byte Sequences

Byte Sequences can be conveyed in Structured Fields.¶

The ABNF for a Byte Sequence is:¶

sf-binary = ":" *(base64) ":"
base64    = ALPHA / DIGIT / "+" / "/" / "="

A Byte Sequence is delimited with colons and encoded using base64 ([RFC4648], Section 4). For example:¶

Example-ByteSequence: :cHJldGVuZCB0aGlzIGlzIGJpbmFyeSBjb250ZW50Lg==:

Parsers MUST support Byte Sequences with at least 16384 octets after decoding.¶

3.3.6. Booleans

Boolean values can be conveyed in Structured Fields.¶

The ABNF for a Boolean is:¶

sf-boolean = "?" boolean
boolean    = "0" / "1"

A Boolean is indicated with a leading "?" character followed by a "1" for a true value or "0" for false. For example:¶

Example-Boolean: ?1

Note that in Dictionary (Section 3.2) and Parameter (Section 3.1.2) values, Boolean true is indicated by omitting the value.¶

4. Working with Structured Fields in HTTP

This section defines how to serialize and parse Structured Fields in textual HTTP field values and other encodings compatible with them (e.g., in HTTP/2 [RFC7540] before compression with HPACK [RFC7541]).¶

4.1. Serializing Structured Fields

Given a structure defined in this specification, return an ASCII string suitable for use in an HTTP field value.¶

If the structure is a Dictionary or List and its value is empty (i.e., it has no members), do not serialize the field at all (i.e., omit both the field-name and field-value).
If the structure is a List, let output_string be the result of running Serializing a List (Section 4.1.1) with the structure.
Else, if the structure is a Dictionary, let output_string be the result of running Serializing a Dictionary (Section 4.1.2) with the structure.
Else, if the structure is an Item, let output_string be the result of running Serializing an Item (Section 4.1.3) with the structure.
Else, fail serialization.
Return output_string converted into an array of bytes, using ASCII encoding [RFC0020].

4.1.1. Serializing a List

Given an array of (member_value, parameters) tuples as input_list, return an ASCII string suitable for use in an HTTP field value.¶

Let output be an empty string.
For each (member_value, parameters) of input_list:
1. If member_value is an array, append the result of running Serializing an Inner List (Section 4.1.1.1) with (member_value, parameters) to output.
2. Otherwise, append the result of running Serializing an Item (Section 4.1.3) with (member_value, parameters) to output.
3. If more member_values remain in input_list:
  1. Append "," to output.
  2. Append a single SP to output.
Return output.

4.1.1.1. Serializing an Inner List

Given an array of (member_value, parameters) tuples as inner_list, and parameters as list_parameters, return an ASCII string suitable for use in an HTTP field value.¶

Let output be the string "(".
For each (member_value, parameters) of inner_list:
1. Append the result of running Serializing an Item (Section 4.1.3) with (member_value, parameters) to output.
2. If more values remain in inner_list, append a single SP to output.
Append ")" to output.
Append the result of running Serializing Parameters (Section 4.1.1.2) with list_parameters to output.
Return output.

4.1.1.2. Serializing Parameters

Given an ordered Dictionary as input_parameters (each member having a param_key and a param_value), return an ASCII string suitable for use in an HTTP field value.¶

Let output be an empty string.
For each param_key with a value of param_value in input_parameters:
1. Append ";" to output.
2. Append the result of running Serializing a Key (Section 4.1.1.3) with param_key to output.
3. If param_value is not Boolean true:
  1. Append "=" to output.
  2. Append the result of running Serializing a bare Item (Section 4.1.3.1) with param_value to output.
Return output.

4.1.1.3. Serializing a Key

Given a key as input_key, return an ASCII string suitable for use in an HTTP field value.¶

Convert input_key into a sequence of ASCII characters; if conversion fails, fail serialization.
If input_key contains characters not in lcalpha, DIGIT, "_", "-", ".", or "*", fail serialization.
If the first character of input_key is not lcalpha or "*", fail serialization.
Let output be an empty string.
Append input_key to output.
Return output.

4.1.2. Serializing a Dictionary

Given an ordered Dictionary as input_dictionary (each member having a member_key and a tuple value of (member_value, parameters)), return an ASCII string suitable for use in an HTTP field value.¶

Let output be an empty string.
For each member_key with a value of (member_value, parameters) in input_dictionary:
1. Append the result of running Serializing a Key (Section 4.1.1.3) with member's member_key to output.
2. If member_value is Boolean true:
  1. Append the result of running Serializing Parameters (Section 4.1.1.2) with parameters to output.
3. Otherwise:
  1. Append "=" to output.
  2. If member_value is an array, append the result of running Serializing an Inner List (Section 4.1.1.1) with (member_value, parameters) to output.
  3. Otherwise, append the result of running Serializing an Item (Section 4.1.3) with (member_value, parameters) to output.
4. If more members remain in input_dictionary:
  1. Append "," to output.
  2. Append a single SP to output.
Return output.

4.1.3. Serializing an Item

Given an Item as bare_item and Parameters as item_parameters, return an ASCII string suitable for use in an HTTP field value.¶

Let output be an empty string.
Append the result of running Serializing a Bare Item (Section 4.1.3.1) with bare_item to output.
Append the result of running Serializing Parameters (Section 4.1.1.2) with item_parameters to output.
Return output.

4.1.3.1. Serializing a Bare Item

Given an Item as input_item, return an ASCII string suitable for use in an HTTP field value.¶

If input_item is an Integer, return the result of running Serializing an Integer (Section 4.1.4) with input_item.
If input_item is a Decimal, return the result of running Serializing a Decimal (Section 4.1.5) with input_item.
If input_item is a String, return the result of running Serializing a String (Section 4.1.6) with input_item.
If input_item is a Token, return the result of running Serializing a Token (Section 4.1.7) with input_item.
If input_item is a Byte Sequence, return the result of running Serializing a Byte Sequence (Section 4.1.8) with input_item.
If input_item is a Boolean, return the result of running Serializing a Boolean (Section 4.1.9) with input_item.
Otherwise, fail serialization.

4.1.4. Serializing an Integer

Given an Integer as input_integer, return an ASCII string suitable for use in an HTTP field value.¶

If input_integer is not an integer in the range of -999,999,999,999,999 to 999,999,999,999,999 inclusive, fail serialization.
Let output be an empty string.
If input_integer is less than (but not equal to) 0, append "-" to output.
Append input_integer's numeric value represented in base 10 using only decimal digits to output.
Return output.

4.1.5. Serializing a Decimal

Given a decimal number as input_decimal, return an ASCII string suitable for use in an HTTP field value.¶

If input_decimal is not a decimal number, fail serialization.
If input_decimal has more than three significant digits to the right of the decimal point, round it to three decimal places, rounding the final digit to the nearest value, or to the even value if it is equidistant.
If input_decimal has more than 12 significant digits to the left of the decimal point after rounding, fail serialization.
Let output be an empty string.
If input_decimal is less than (but not equal to) 0, append "-" to output.
Append input_decimal's integer component represented in base 10 (using only decimal digits) to output; if it is zero, append "0".
Append "." to output.
If input_decimal's fractional component is zero, append "0" to output.
Otherwise, append the significant digits of input_decimal's fractional component represented in base 10 (using only decimal digits) to output.
Return output.

4.1.6. Serializing a String

Given a String as input_string, return an ASCII string suitable for use in an HTTP field value.¶

Convert input_string into a sequence of ASCII characters; if conversion fails, fail serialization.
If input_string contains characters in the range %x00-1f or %x7f-ff (i.e., not in VCHAR or SP), fail serialization.
Let output be the string DQUOTE.
For each character char in input_string:
1. If char is "\" or DQUOTE:
  1. Append "\" to output.
2. Append char to output.
Append DQUOTE to output.
Return output.

4.1.7. Serializing a Token

Given a Token as input_token, return an ASCII string suitable for use in an HTTP field value.¶

Convert input_token into a sequence of ASCII characters; if conversion fails, fail serialization.
If the first character of input_token is not ALPHA or "*", or the remaining portion contains a character not in tchar, ":", or "/", fail serialization.
Let output be an empty string.
Append input_token to output.
Return output.

4.1.8. Serializing a Byte Sequence

Given a Byte Sequence as input_bytes, return an ASCII string suitable for use in an HTTP field value.¶

If input_bytes is not a sequence of bytes, fail serialization.
Let output be an empty string.
Append ":" to output.
Append the result of base64-encoding input_bytes as per [RFC4648], Section 4, taking account of the requirements below.
Append ":" to output.
Return output.

The encoded data is required to be padded with "=", as per [RFC4648], Section 3.2.¶

Likewise, encoded data SHOULD have pad bits set to zero, as per [RFC4648], Section 3.5, unless it is not possible to do so due to implementation constraints.¶

4.1.9. Serializing a Boolean

Given a Boolean as input_boolean, return an ASCII string suitable for use in an HTTP field value.¶

If input_boolean is not a boolean, fail serialization.
Let output be an empty string.
Append "?" to output.
If input_boolean is true, append "1" to output.
If input_boolean is false, append "0" to output.
Return output.

4.2. Parsing Structured Fields

When a receiving implementation parses HTTP fields that are known to be Structured Fields, it is important that care be taken, as there are a number of edge cases that can cause interoperability or even security problems. This section specifies the algorithm for doing so.¶

Given an array of bytes as input_bytes that represent the chosen field's field-value (which is empty if that field is not present) and field_type (one of "dictionary", "list", or "item"), return the parsed header value.¶

Convert input_bytes into an ASCII string input_string; if conversion fails, fail parsing.
Discard any leading SP characters from input_string.
If field_type is "list", let output be the result of running Parsing a List (Section 4.2.1) with input_string.
If field_type is "dictionary", let output be the result of running Parsing a Dictionary (Section 4.2.2) with input_string.
If field_type is "item", let output be the result of running Parsing an Item (Section 4.2.3) with input_string.
Discard any leading SP characters from input_string.
If input_string is not empty, fail parsing.
Otherwise, return output.

When generating input_bytes, parsers MUST combine all field lines in the same section (header or trailer) that case-insensitively match the field name into one comma-separated field-value, as per [RFC7230], Section 3.2.2; this assures that the entire field value is processed correctly.¶

For Lists and Dictionaries, this has the effect of correctly concatenating all of the field's lines, as long as individual members of the top-level data structure are not split across multiple header instances. The parsing algorithms for both types allow tab characters, since these might be used to combine field lines by some implementations.¶

Strings split across multiple field lines will have unpredictable results, because one or more commas (with optional whitespace) will become part of the string output by the parser. Since concatenation might be done by an upstream intermediary, the results are not under the control of the serializer or the parser, even when they are both under the control of the same party.¶

Tokens, Integers, Decimals, and Byte Sequences cannot be split across multiple field lines because the inserted commas will cause parsing to fail.¶

Parsers MAY fail when processing a field value spread across multiple field lines, when one of those lines does not parse as that field. For example, a parsing handling an Example-String field that's defined as an sf-string is allowed to fail when processing this field section:¶

Example-String: "foo
Example-String: bar"

If parsing fails -- including when calling another algorithm -- the entire field value MUST be ignored (i.e., treated as if the field were not present in the section). This is intentionally strict, to improve interoperability and safety, and specifications referencing this document are not allowed to loosen this requirement.¶

Note that this requirement does not apply to an implementation that is not parsing the field; for example, an intermediary is not required to strip a failing field from a message before forwarding it.¶

4.2.1. Parsing a List

Given an ASCII string as input_string, return an array of (item_or_inner_list, parameters) tuples. input_string is modified to remove the parsed value.¶

Let members be an empty array.
While input_string is not empty:
1. Append the result of running Parsing an Item or Inner List (Section 4.2.1.1) with input_string to members.
2. Discard any leading OWS characters from input_string.
3. If input_string is empty, return members.
4. Consume the first character of input_string; if it is not ",", fail parsing.
5. Discard any leading OWS characters from input_string.
6. If input_string is empty, there is a trailing comma; fail parsing.
No structured data has been found; return members (which is empty).

4.2.1.1. Parsing an Item or Inner List

Given an ASCII string as input_string, return the tuple (item_or_inner_list, parameters), where item_or_inner_list can be either a single bare item or an array of (bare_item, parameters) tuples. input_string is modified to remove the parsed value.¶

If the first character of input_string is "(", return the result of running Parsing an Inner List (Section 4.2.1.2) with input_string.
Return the result of running Parsing an Item (Section 4.2.3) with input_string.

4.2.1.2. Parsing an Inner List

Given an ASCII string as input_string, return the tuple (inner_list, parameters), where inner_list is an array of (bare_item, parameters) tuples. input_string is modified to remove the parsed value.¶

Consume the first character of input_string; if it is not "(", fail parsing.
Let inner_list be an empty array.
While input_string is not empty:
1. Discard any leading SP characters from input_string.
2. If the first character of input_string is ")":
  1. Consume the first character of input_string.
  2. Let parameters be the result of running Parsing Parameters (Section 4.2.3.2) with input_string.
  3. Return the tuple (inner_list, parameters).
3. Let item be the result of running Parsing an Item (Section 4.2.3) with input_string.
4. Append item to inner_list.
5. If the first character of input_string is not SP or ")", fail parsing.
The end of the Inner List was not found; fail parsing.

4.2.2. Parsing a Dictionary

Given an ASCII string as input_string, return an ordered map whose values are (item_or_inner_list, parameters) tuples. input_string is modified to remove the parsed value.¶

Let dictionary be an empty, ordered map.
While input_string is not empty:
1. Let this_key be the result of running Parsing a Key (Section 4.2.3.3) with input_string.
2. If the first character of input_string is "=":
  1. Consume the first character of input_string.
  2. Let member be the result of running Parsing an Item or Inner List (Section 4.2.1.1) with input_string.
3. Otherwise:
  1. Let value be Boolean true.
  2. Let parameters be the result of running Parsing Parameters (Section 4.2.3.2) with input_string.
  3. Let member be the tuple (value, parameters).
4. If dictionary already contains a key this_key (comparing character for character), overwrite its value with member.
5. Otherwise, append key this_key with value member to dictionary.
6. Discard any leading OWS characters from input_string.
7. If input_string is empty, return dictionary.
8. Consume the first character of input_string; if it is not ",", fail parsing.
9. Discard any leading OWS characters from input_string.
10. If input_string is empty, there is a trailing comma; fail parsing.
No structured data has been found; return dictionary (which is empty).

Note that when duplicate Dictionary keys are encountered, all but the last instance are ignored.¶

4.2.3. Parsing an Item

Given an ASCII string as input_string, return a (bare_item, parameters) tuple. input_string is modified to remove the parsed value.¶

Let bare_item be the result of running Parsing a Bare Item (Section 4.2.3.1) with input_string.
Let parameters be the result of running Parsing Parameters (Section 4.2.3.2) with input_string.
Return the tuple (bare_item, parameters).

4.2.3.1. Parsing a Bare Item

Given an ASCII string as input_string, return a bare Item. input_string is modified to remove the parsed value.¶

If the first character of input_string is a "-" or a DIGIT, return the result of running Parsing an Integer or Decimal (Section 4.2.4) with input_string.
If the first character of input_string is a DQUOTE, return the result of running Parsing a String (Section 4.2.5) with input_string.
If the first character of input_string is an ALPHA or "*", return the result of running Parsing a Token (Section 4.2.6) with input_string.
If the first character of input_string is ":", return the result of running Parsing a Byte Sequence (Section 4.2.7) with input_string.
If the first character of input_string is "?", return the result of running Parsing a Boolean (Section 4.2.8) with input_string.
Otherwise, the item type is unrecognized; fail parsing.

4.2.3.2. Parsing Parameters

Given an ASCII string as input_string, return an ordered map whose values are bare Items. input_string is modified to remove the parsed value.¶

Let parameters be an empty, ordered map.
While input_string is not empty:
1. If the first character of input_string is not ";", exit the loop.
2. Consume the ";" character from the beginning of input_string.
3. Discard any leading SP characters from input_string.
4. Let param_key be the result of running Parsing a Key (Section 4.2.3.3) with input_string.
5. Let param_value be Boolean true.
6. If the first character of input_string is "=":
  1. Consume the "=" character at the beginning of input_string.
  2. Let param_value be the result of running Parsing a Bare Item (Section 4.2.3.1) with input_string.
7. If parameters already contains a key param_key (comparing character for character), overwrite its value with param_value.
8. Otherwise, append key param_key with value param_value to parameters.
Return parameters.

Note that when duplicate parameter keys are encountered, all but the last instance are ignored.¶

4.2.3.3. Parsing a Key

Given an ASCII string as input_string, return a key. input_string is modified to remove the parsed value.¶

If the first character of input_string is not lcalpha or "*", fail parsing.
Let output_string be an empty string.
While input_string is not empty:
1. If the first character of input_string is not one of lcalpha, DIGIT, "_", "-", ".", or "*", return output_string.
2. Let char be the result of consuming the first character of input_string.
3. Append char to output_string.
Return output_string.

4.2.4. Parsing an Integer or Decimal

Given an ASCII string as input_string, return an Integer or Decimal. input_string is modified to remove the parsed value.¶

NOTE: This algorithm parses both Integers (Section 3.3.1) and Decimals (Section 3.3.2), and returns the corresponding structure.¶

Let type be "integer".
Let sign be 1.
Let input_number be an empty string.
If the first character of input_string is "-", consume it and set sign to -1.
If input_string is empty, there is an empty integer; fail parsing.
If the first character of input_string is not a DIGIT, fail parsing.
While input_string is not empty:
1. Let char be the result of consuming the first character of input_string.
2. If char is a DIGIT, append it to input_number.
3. Else, if type is "integer" and char is ".":
  1. If input_number contains more than 12 characters, fail parsing.
  2. Otherwise, append char to input_number and set type to "decimal".
4. Otherwise, prepend char to input_string, and exit the loop.
5. If type is "integer" and input_number contains more than 15 characters, fail parsing.
6. If type is "decimal" and input_number contains more than 16 characters, fail parsing.
If type is "integer":
1. Parse input_number as an integer and let output_number be the product of the result and sign.
Otherwise:
1. If the final character of input_number is ".", fail parsing.
2. If the number of characters after "." in input_number is greater than three, fail parsing.
3. Parse input_number as a decimal number and let output_number be the product of the result and sign.
Return output_number.

4.2.5. Parsing a String

Given an ASCII string as input_string, return an unquoted String. input_string is modified to remove the parsed value.¶

Let output_string be an empty string.
If the first character of input_string is not DQUOTE, fail parsing.
Discard the first character of input_string.
While input_string is not empty:
1. Let char be the result of consuming the first character of input_string.
2. If char is a backslash ("\"):
  1. If input_string is now empty, fail parsing.
  2. Let next_char be the result of consuming the first character of input_string.
  3. If next_char is not DQUOTE or "\", fail parsing.
  4. Append next_char to output_string.
3. Else, if char is DQUOTE, return output_string.
4. Else, if char is in the range %x00-1f or %x7f-ff (i.e., it is not in VCHAR or SP), fail parsing.
5. Else, append char to output_string.
Reached the end of input_string without finding a closing DQUOTE; fail parsing.

4.2.6. Parsing a Token

Given an ASCII string as input_string, return a Token. input_string is modified to remove the parsed value.¶

If the first character of input_string is not ALPHA or "*", fail parsing.
Let output_string be an empty string.
While input_string is not empty:
1. If the first character of input_string is not in tchar, ":", or "/", return output_string.
2. Let char be the result of consuming the first character of input_string.
3. Append char to output_string.
Return output_string.

4.2.7. Parsing a Byte Sequence

Given an ASCII string as input_string, return a Byte Sequence. input_string is modified to remove the parsed value.¶

If the first character of input_string is not ":", fail parsing.
Discard the first character of input_string.
If there is not a ":" character before the end of input_string, fail parsing.
Let b64_content be the result of consuming content of input_string up to but not including the first instance of the character ":".
Consume the ":" character at the beginning of input_string.
If b64_content contains a character not included in ALPHA, DIGIT, "+", "/", and "=", fail parsing.
Let binary_content be the result of base64-decoding [RFC4648] b64_content, synthesizing padding if necessary (note the requirements about recipient behavior below). If base64 decoding fails, parsing fails.
Return binary_content.

Because some implementations of base64 do not allow rejection of encoded data that is not properly "=" padded (see [RFC4648], Section 3.2), parsers SHOULD NOT fail when "=" padding is not present, unless they cannot be configured to do so.¶

Because some implementations of base64 do not allow rejection of encoded data that has non-zero pad bits (see [RFC4648], Section 3.5), parsers SHOULD NOT fail when non-zero pad bits are present, unless they cannot be configured to do so.¶

This specification does not relax the requirements in [RFC4648], Sections 3.1 and 3.3; therefore, parsers MUST fail on characters outside the base64 alphabet and on line feeds in encoded data.¶

4.2.8. Parsing a Boolean

Given an ASCII string as input_string, return a Boolean. input_string is modified to remove the parsed value.¶

If the first character of input_string is not "?", fail parsing.
Discard the first character of input_string.
If the first character of input_string matches "1", discard the first character, and return true.
If the first character of input_string matches "0", discard the first character, and return false.
No value has matched; fail parsing.