Indicating Character Encoding and Language for HTTP Header Field Parameters

Abstract

By default, message header field parameters in Hypertext Transfer Protocol (HTTP) messages cannot carry characters outside the ISO-8859-1 character set. RFC 2231 defines an encoding mechanism for use in Multipurpose Internet Mail Extensions (MIME) headers. This document specifies an encoding suitable for use in HTTP header fields that is compatible with a profile of the encoding defined in RFC 2231.¶

Status of This Memo

This Internet-Draft is submitted in full conformance with the provisions of BCP 78 and BCP 79.¶

Internet-Drafts are working documents of the Internet Engineering Task Force (IETF). Note that other groups may also distribute working documents as Internet-Drafts. The list of current Internet-Drafts is at https://datatracker.ietf.org/drafts/current/.¶

Internet-Drafts are draft documents valid for a maximum of six months and may be updated, replaced, or obsoleted by other documents at any time. It is inappropriate to use Internet-Drafts as reference material or to cite them other than as “work in progress”.¶

This Internet-Draft will expire on January 8, 2025.¶

Copyright Notice

This document is subject to BCP 78 and the IETF Trust's Legal Provisions Relating to IETF Documents (https://trustee.ietf.org/license-info) in effect on the date of publication of this document. Please review these documents carefully, as they describe your rights and restrictions with respect to this document. Code Components extracted from this document must include Revised BSD License text as described in Section 4.e of the Trust Legal Provisions and are provided without warranty as described in the Revised BSD License.¶

1. Introduction

By default, message header field parameters in HTTP ([RFC2616]) messages cannot carry characters outside the ISO-8859-1 coded character set ([ISO-8859-1]). RFC 2231 ([RFC2231]) defines an encoding mechanism for use in MIME headers. This document specifies an encoding suitable for use in HTTP header fields that is compatible with a profile of the encoding defined in RFC 2231.¶

This document obsoletes [RFC5987] and moves it to "historic" status; the changes are summarized in Appendix A.¶

2. Notational Conventions

The key words "MUST", "MUST NOT", "REQUIRED", "SHALL", "SHALL NOT", "SHOULD", "SHOULD NOT", "RECOMMENDED", "MAY", and "OPTIONAL" in this document are to be interpreted as described in [RFC2119].¶

This specification uses the ABNF (Augmented Backus-Naur Form) notation defined in [RFC5234]. The following core rules are included by reference, as defined in [RFC5234], Appendix B.1: ALPHA (letters), DIGIT (decimal 0-9), HEXDIG (hexadecimal 0-9/A-F/a-f), and LWSP (linear whitespace).¶

This specification uses terminology defined in [RFC6365], namely: "character encoding scheme" (below abbreviated to "character encoding"), "charset" and "coded character set".¶

Note that this differs from RFC 2231, which uses the term "character set" for "character encoding scheme".¶

3. Comparison to RFC 2231 and Definition of the Encoding

RFC 2231 defines several extensions to MIME. The sections below discuss if and how they apply to HTTP header fields.¶

In short: ¶

Parameter Continuations aren't needed (Section 3.1),
Character Encoding and Language Information are useful, therefore a simple subset is specified (Section 3.2), and
Language Specifications in Encoded Words aren't needed (Section 3.3).

3.1. Parameter Continuations

Section 3 of [RFC2231] defines a mechanism that deals with the length limitations that apply to MIME headers. These limitations do not apply to HTTP ([RFC7231], Appendix A.6).¶

Thus, parameter continuations are not part of the encoding defined by this specification.¶

3.2. Parameter Value Character Encoding and Language Information

Section 4 of [RFC2231] specifies how to embed language information into parameter values, and also how to encode non-ASCII characters, dealing with restrictions both in MIME and HTTP header field parameters.¶

However, RFC 2231 does not specify a mandatory-to-implement character encoding, making it hard for senders to decide which encoding to use. Thus, recipients implementing this specification MUST support the "UTF-8" character encoding [RFC3629].¶

Furthermore, RFC 2231 allows the character encoding information to be left out. The encoding defined by this specification does not allow that.¶

3.2.1. Definition

The syntax for parameters is defined in Section 3.6 of [RFC2616] (with RFC 2616 implied LWS translated to RFC 5234 LWSP):¶

  parameter     = attribute LWSP "=" LWSP value

  attribute     = token
  value         = token / quoted-string

  quoted-string = <quoted-string, defined in [RFC7230], Section 3.2.6>
  token         = <token, defined in [RFC7230], Section 3.2.6>

In order to include character encoding and language information, this specification modifies the RFC 2616 grammar to be:¶

  parameter     = reg-parameter / ext-parameter

  reg-parameter = parmname LWSP "=" LWSP value

  ext-parameter = parmname "*" LWSP "=" LWSP ext-value

  parmname      = 1*attr-char

  ext-value     = charset  "'" [ language ] "'" value-chars
                ; like RFC 2231's <extended-initial-value>
                ; (see [RFC2231], Section 7)

  charset       = "UTF-8" / mime-charset

  mime-charset  = 1*mime-charsetc
  mime-charsetc = ALPHA / DIGIT
                / "!" / "#" / "$" / "%" / "&"
                / "+" / "-" / "^" / "_" / "`"
                / "{" / "}" / "~"
                ; as <mime-charset> in Section 2.3 of [RFC2978]
                ; except that the single quote is not included
                ; SHOULD be registered in the IANA charset registry

  language      = <Language-Tag, defined in [RFC5646], Section 2.1>

  value-chars   = *( pct-encoded / attr-char )

  pct-encoded   = "%" HEXDIG HEXDIG
                ; see [RFC3986], Section 2.1

  attr-char     = ALPHA / DIGIT
                / "!" / "#" / "$" / "&" / "+" / "-" / "."
                / "^" / "_" / "`" / "|" / "~"
                ; token except ( "*" / "'" / "%" )

Thus, a parameter is either a regular parameter (reg-parameter), as previously defined in Section 3.6 of [RFC2616], or an extended parameter (ext-parameter).¶

Extended parameters are those where the left-hand side of the assignment ends with an asterisk character.¶

The value part of an extended parameter (ext-value) is a token that consists of three parts: the REQUIRED character encoding name (charset), the OPTIONAL language information (language), and a character sequence representing the actual value (value-chars), separated by single quote characters. Note that both character encoding names and language tags are restricted to the US-ASCII coded character set, and are matched case-insensitively (see [RFC2978], Section 2.3 and [RFC5646], Section 2.1.1).¶

Inside the value part, characters not contained in attr-char are encoded into an octet sequence using the specified character encoding. That octet sequence is then percent-encoded as specified in Section 2.1 of [RFC3986].¶

Producers MUST use the "UTF-8" ([RFC3629]) character encoding. Extension character encodings (mime-charset) are reserved for future use.¶

3.2.2. Historical Notes

The RFC 7230 token production ([RFC7230], Section 3.2.6) differs from the production used in RFC 2231 (imported from Section 5.1 of [RFC2045]) in that curly braces ("{" and "}") are excluded. Thus, these two characters are excluded from the attr-char production as well.¶

The <mime-charset> ABNF defined here differs from the one in Section 2.3 of [RFC2978] in that it does not allow the single quote character (see also RFC Errata ID 1912 [Err1912]). In practice, no character encoding names using that character have been registered at the time of this writing.¶

For backwards compatibility with RFC 2231, the encoding defined by this specification deviates from common parameter syntax in that the quoted-string notation is not allowed. Implementations using generic parser components might not be able to detect the use of quoted-string notation and thus might accept that format, although invalid, as well.¶

[RFC5987] did require support for ISO-8859-1, too; for compatibility with legacy code, recipients are encouraged to support this encoding as well.¶

3.2.3. Examples

Non-extended notation, using "token":

  foo: bar; title=Economy

Non-extended notation, using "quoted-string":

  foo: bar; title="US-$ rates"

Extended notation, using the Unicode character U+00A3 (POUND SIGN):

  foo: bar; title*=utf-8'en'%C2%A3%20rates

Note: the Unicode pound sign character U+00A3 was encoded into the octet sequence C2 A3 using the UTF-8 character encoding, then percent-encoded. Also, note that the space character was encoded as %20, as it is not contained in attr-char.

Extended notation, using the Unicode characters U+00A3 (POUND SIGN) and U+20AC (EURO SIGN):

  foo: bar; title*=UTF-8''%c2%a3%20and%20%e2%82%ac%20rates

Note: the Unicode pound sign character U+00A3 was encoded into the octet sequence C2 A3 using the UTF-8 character encoding, then percent-encoded. Likewise, the Unicode euro sign character U+20AC was encoded into the octet sequence E2 82 AC, then percent-encoded. Also note that HEXDIG allows both lowercase and uppercase characters, so recipients must understand both, and that the language information is optional, while the character encoding is not.

3.3. Language Specification in Encoded Words

Section 5 of [RFC2231] extends the encoding defined in [RFC2047] to also support language specification in encoded words. RFC 2616, the now-obsolete HTTP/1.1 specification, did refer to RFC 2047 ([RFC2616], Section 2.2). However, it wasn't clear to which header field it applied. Consequently, the current revision of the HTTP/1.1 specification has deprecated use of the encoding forms defined in RFC 2047 (see Section 3.2.4 of [RFC7230]).¶

Thus, this specification does not include this feature.¶

4. Guidelines for Usage in HTTP Header Field Definitions

Specifications of HTTP header fields that use the extensions defined in Section 3.2 ought to clearly state that. A simple way to achieve this is to normatively reference this specification, and to include the ext-value production into the ABNF for that header field.¶

For instance:

  foo-header  = "foo" LWSP ":" LWSP token ";" LWSP title-param
  title-param = "title" LWSP "=" LWSP value
              / "title*" LWSP "=" LWSP ext-value
  ext-value   = <see RFC 5987, Section 3.2>

4.1. When to Use the Extension

Section 4.2 of [RFC2277] requires that protocol elements containing human-readable text are able to carry language information. Thus, the ext-value production ought to be always used when the parameter value is of textual nature and its language is known.¶

Furthermore, the extension ought to also be used whenever the parameter value needs to carry characters not present in the US-ASCII ([USASCII]) coded character set (note that it would be unacceptable to define a new parameter that would be restricted to a subset of the Unicode character set).¶

4.2. Error Handling

Header field specifications need to define whether multiple instances of parameters with identical parmname components are allowed, and how they should be processed. This specification suggests that a parameter using the extended syntax takes precedence. This would allow producers to use both formats without breaking recipients that do not understand the extended syntax yet.¶

Example:

  foo: bar; title="EURO exchange rates";
            title*=utf-8''%e2%82%ac%20exchange%20rates

In this case, the sender provides an ASCII version of the title for legacy recipients, but also includes an internationalized version for recipients understanding this specification -- the latter obviously ought to prefer the new syntax over the old one.

5. Security Considerations

The format described in this document makes it possible to transport non-ASCII characters, and thus enables character "spoofing" scenarios, in which a displayed value appears to be something other than it is.¶

Furthermore, there are known attack scenarios relating to decoding UTF-8.¶

See Section 10 of [RFC3629] for more information on both topics.¶

In addition, the extension specified in this document makes it possible to transport multiple language variants for a single parameter, and such use might allow spoofing attacks, where different language versions of the same parameter are not equivalent. Whether this attack is useful as an attack depends on the parameter specified.¶

6. IANA Considerations

There are no IANA Considerations related to this specification.¶

7. Acknowledgements

Thanks to Martin Duerst and Frank Ellermann for help figuring out ABNF details, to Graham Klyne and Alexey Melnikov for general review, to Chris Newman for pointing out an RFC 2231 incompatibility, and to Benjamin Carlyle, Roar Lauritzsen, Eric Lawrence, and James Manger for implementer's feedback.¶

Appendix A. Changes from RFC 5987

This section summarizes the changes compared to [RFC5987]:¶

The document title was changed to "Indicating Character Encoding and Language for HTTP Header Field Parameters".
The requirement to support the "ISO-8859-1" encoding was removed.

Appendix B. Implementation Report

The encoding defined in this document currently is used for two different HTTP header fields: ¶

"Content-Disposition", defined in [RFC6266], and
"Link", defined in [RFC5988].

As the encoding is a profile/clarification of the one defined in [RFC2231] in 1997, many user agents already supported it for use in "Content-Disposition" when [RFC5987] got published.¶

Since the publication of [RFC5987], three more popular desktop user agents have added support for this encoding; see <http://purl.org/NET/http/content-disposition-tests#encoding-2231-char> for details. At this time, the current versions of all major desktop user agents support it.¶

Note that the implementation in Internet Explorer 9 does not support the ISO-8859-1 character encoding; this document revision acknowledges that UTF-8 is sufficient for expressing all code points, and removes the requirement to support ISO-8859-1.¶

The "Link" header field, on the other hand, was only recently specified in [RFC5988]. At the time of this writing, no shipping User Agent except Firefox supported the "title*" parameter (starting with release 15).¶

E
- Err1912 3.2.2, 8.2
I
- ISO-8859-1 1, 8.2
R
- RFC2045 3.2.2, 8.2
  - Section 5.1 3.2.2
- RFC2047 3.3, 8.2
- RFC2119 2, 8.1
- RFC2231 1, 3.1, 3.2, 3.2.1, 3.3, 4, 8.2, B
  - Section 3 3.1, 4
  - Section 4 3.2
  - Section 5 3.3
  - Section 7 3.2.1
- RFC2277 4.1, 8.2
  - Section 4.2 4.1
- RFC2388 1, 8.2
- RFC2616 1, 3.2.1, 3.2.1, 3.3, 8.1
  - Section 2.2 3.3
  - Section 3.6 3.2.1, 3.2.1
- RFC2978 3.2.1, 3.2.1, 3.2.2, 8.1
  - Section 2.3 3.2.1, 3.2.1, 3.2.2
- RFC3629 3.2, 3.2.1, 5, 8.1
  - Section 10 5
- RFC3986 3.2.1, 3.2.1, 8.1
  - Section 2.1 3.2.1, 3.2.1
- RFC5234 2, 2, 8.1
  - Appendix B.1 2
- RFC5646 3.2.1, 3.2.1, 8.1
  - Section 2.1 3.2.1
  - Section 2.1.1 3.2.1
- RFC5987 1, 3.2.2, 8.2, A, B, B
- RFC5988 8.2, B, B
- RFC6266 8.2, B
- RFC6365 2, 8.2
- RFC7230 3.2.1, 3.2.1, 3.2.2, 3.3, 8.1
  - Section 3.2.4 3.3
  - Section 3.2.6 3.2.1, 3.2.1, 3.2.2
- RFC7231 3.1, 8.1
  - Appendix A.6 3.1
U
- USASCII 4.1, 8.1

I edit (type: edit, status: open)
julian.reschke@greenbytes.de	2011-04-15	Umbrella issue for editorial fixes/enhancements.

I httpbis (type: edit, status: open)
julian.reschke@greenbytes.de	2011-09-17	The document refers normatively to RFC 2616. Should it continue to do so, or should we wait for HTTPbis? This may affect edge case in the ABNF, such as the definition of linear white space or the characters allowed in "token".

Indicating Character Encoding and Language for HTTP Header Field Parameters

Abstract

Editorial Note (To be removed by RFC Editor before publication)

Status of This Memo

Copyright Notice

1. Introduction

2. Notational Conventions

3. Comparison to RFC 2231 and Definition of the Encoding

3.1. Parameter Continuations

3.2. Parameter Value Character Encoding and Language Information

3.2.1. Definition

3.2.2. Historical Notes

3.2.3. Examples

3.3. Language Specification in Encoded Words

4. Guidelines for Usage in HTTP Header Field Definitions

4.1. When to Use the Extension

4.2. Error Handling

5. Security Considerations

6. IANA Considerations

7. Acknowledgements

8. References

8.1. Normative References

8.2. Informative References

Appendix A. Changes from RFC 5987

Appendix B. Implementation Report

Appendix C. Change Log (to be removed by RFC Editor before publication)

C.1. Since RFC5987

C.2. Since draft-reschke-rfc5987bis-00

C.3. Since draft-reschke-rfc5987bis-01

C.4. Since draft-reschke-rfc5987bis-02

C.5. Since draft-reschke-rfc5987bis-03

C.6. Since draft-reschke-rfc5987bis-04

C.7. Since draft-reschke-rfc5987bis-05

C.8. Since draft-reschke-rfc5987bis-06

Index

Author's Address

Id	Type	Status	Date	Raised By
edit	edit	open	2011-04-15	julian.reschke@greenbytes.de
httpbis	edit	open	2011-09-17	julian.reschke@greenbytes.de