Application of RFC 2231 Encoding to Hypertext Transfer Protocol (HTTP) Header Fields

Abstract

By default, message header field parameters in Hypertext Transfer Protocol (HTTP) messages can not carry characters outside the ISO-8859-1 character set. RFC 2231 defines an escaping mechanism for use in Multipurpose Internet Mail Extensions (MIME) headers. This document specifies a profile of that encoding suitable for use in HTTP header fields.¶

Status of this Memo

This Internet-Draft is submitted to IETF in full conformance with the provisions of BCP 78 and BCP 79.¶

Internet-Drafts are working documents of the Internet Engineering Task Force (IETF), its areas, and its working groups. Note that other groups may also distribute working documents as Internet-Drafts.¶

Internet-Drafts are draft documents valid for a maximum of six months and may be updated, replaced, or obsoleted by other documents at any time. It is inappropriate to use Internet-Drafts as reference material or to cite them other than as “work in progress”.¶

The list of current Internet-Drafts can be accessed at http://www.ietf.org/ietf/1id-abstracts.txt.¶

The list of Internet-Draft Shadow Directories can be accessed at http://www.ietf.org/shadow.html.¶

This Internet-Draft will expire on August 25, 2010.¶

Copyright Notice

This document is subject to BCP 78 and the IETF Trust's Legal Provisions Relating to IETF Documents (http://trustee.ietf.org/license-info) in effect on the date of publication of this document. Please review these documents carefully, as they describe your rights and restrictions with respect to this document. Code Components extracted from this document must include Simplified BSD License text as described in Section 4.e of the Trust Legal Provisions and are provided without warranty as described in the BSD License.¶

1. Introduction

By default, message header field parameters in HTTP ([RFC2616]) messages can not carry characters outside the ISO-8859-1 character set ([ISO-8859-1]). RFC 2231 ([RFC2231]) defines an escaping mechanism for use in MIME headers. This document specifies a profile of that encoding for use in HTTP header fields.¶

2. Notational Conventions

The key words "MUST", "MUST NOT", "REQUIRED", "SHALL", "SHALL NOT", "SHOULD", "SHOULD NOT", "RECOMMENDED", "MAY", and "OPTIONAL" in this document are to be interpreted as described in [RFC2119].¶

This specification uses the ABNF (Augmented Backus-Naur Form) notation defined in [RFC5234]. The following core rules are included by reference, as defined in [RFC5234], Appendix B.1: ALPHA (letters), DIGIT (decimal 0-9), HEXDIG (hexadecimal 0-9/A-F/a-f) and LWSP (linear white space).¶

Note that this specification uses the term "character set" for consistency with other IETF specifications such as RFC 2277 (see [RFC2277], Section 3). A more accurate term would be "character encoding" (a mapping of code points to octet sequences).¶

3. A Profile of RFC 2231 for Use in HTTP

RFC 2231 defines several extensions to MIME. The sections below discuss if and how they apply to HTTP.¶

In short: ¶

Parameter Continuations aren't needed (Section 3.1),
Character Set and Language Information are useful, therefore a simple subset is specified (Section 3.2), and
Language Specifications in Encoded Words aren't needed (Section 3.3).

3.1. Parameter Continuations

Section 3 of [RFC2231] defines a mechanism that deals with the length limitations that apply to MIME headers. These limitations do not apply to HTTP ([RFC2616], Section 19.4.7).¶

Thus in HTTP, senders MUST NOT use parameter continuations, and therefore recipients do not need to support them.¶

3.2. Parameter Value Character Set and Language Information

Section 4 of [RFC2231] specifies how to embed language information into parameter values, and also how to encode non-ASCII characters, dealing with restrictions both in MIME and HTTP header parameters.¶

However, RFC 2231 does not specify a mandatory-to-implement character set, making it hard for senders to decide which character set to use. Thus, recipients implementing this specification MUST support the character sets "ISO-8859-1" [ISO-8859-1] and "UTF-8" [RFC3629].¶

Furthermore, RFC 2231 allows leaving out the character set information. The profile defined by this specification does not allow that.¶

The syntax for parameters is defined in Section 3.6 of [RFC2616] (with RFC 2616 implied LWS translated to RFC 5234 LWSP):¶

  parameter     = attribute LWSP "=" LWSP value

  attribute     = token
  value         = token / quoted-string

  quoted-string = <quoted-string, defined in [RFC2616], Section 2.2>
  token         = <token, defined in [RFC2616], Section 2.2>

This specification extends the grammar to:¶

  parameter     = reg-parameter / ext-parameter
   
  reg-parameter = attribute LWSP "=" LWSP value

  ext-parameter = attribute "*" LWSP "=" LWSP ext-value

  ext-value     = charset  "'" [ language ] "'" value-chars
                ; extended-initial-value,
                ; defined in [RFC2231], Section 7

  charset       = "UTF-8" / "ISO-8859-1" / mime-charset
                
  mime-charset  = 1*mime-charsetc
  mime-charsetc = ALPHA / DIGIT
                / "!" / "#" / "$" / "%" / "&"
                / "+" / "-" / "^" / "_" / "`"
                / "{" / "}" / "~"
                ; as <mime-charset> in Section 2.3 of [RFC2978]
                ; except that the single quote is not included
  
  language      = <Language-Tag, defined in [RFC5646], Section 2.1>
  
  value-chars   = *( pct-encoded / attr-char )

  pct-encoded   = "%" HEXDIG HEXDIG
                ; see [RFC3986], Section 2.1

  attr-char     = ALPHA / DIGIT
                / "!" / "#" / "$" / "&" / "+" / "-" / "."
                / "^" / "_" / "`" / "|" / "~"
                ; token except ( "*" / "'" / "%" )

Thus, a parameter is either regular parameter (reg-parameter), as previously defined in Section 3.6 of [RFC2616], or an extended parameter (ext-parameter).¶

I parameter-abnf (type: change, status: open)
julian.reschke@greenbytes.de	2010-02-20	The ABNF for reg-parameter and ext-parameter is ambiguous, as "" is a valid token character; furthermore, RFC 2616's "attribute" production allows "" while RFC 2231's does not. (reported by Alexey Melnikov).
julian.reschke@greenbytes.de	2010-02-21	Proposal: destrict the allowable character set in parameter names to exclude "*" (amd maybe even more non-name characters?). Also, consider extending the set of value characters (for the right hand side) to allow more characters that can be umabigouously parsed outside quoted strings, such as "/".

Extended parameters are those where the left hand side of the assignment ends with an asterisk character.¶

I rfc2978-normative (type: change, status: closed)
julian.reschke@greenbytes.de	2010-02-20	The reference to RFC2978 needs to be normative (reported by Alexey Melnikov).
	2010-02-20	Resolution:Done.

The value part of an extended parameter (ext-value) is a token that consists of three parts: the REQUIRED character set name (charset), the OPTIONAL language information (language), and a character sequence representing the actual value (value-chars), separated by single quote characters. Note that both character set names and language tags are restricted to the US-ASCII character set, and are matched case-insensitively (see [RFC2978], Section 2.3 and [RFC5646], Section 2.1.1).¶

I rfc3986-normative (type: change, status: closed)
julian.reschke@greenbytes.de	2010-02-20	The reference to percent-encoding (RFC3986) needs to be normative (reported by Alexey Melnikov).
	2010-02-20	Resolution:Done.
Associated changes in this document: 8.1, 8.2.

Inside the value part, characters not contained in attr-char are encoded into an octet sequence using the specified character set. That octet sequence then is percent-encoded as specified in Section 2.1 of [RFC3986].¶

I iso8859 (type: change, status: open)
julian.reschke@greenbytes.de	2010-02-20	The protocol could be further simplified by mandating UTF-8 only (reported by Alexey Melnikov). On the other hand and not surprinsingly, testing shows that ISO-8859-1 support is widely implemented. The author is looking for community feedback on this choice.

Producers MUST NOT use character sets other than "UTF-8" ([RFC3629]) or "ISO-8859-1" ([ISO-8859-1]). Extension character sets (ext-charset) are reserved for future use.¶

3.2.1. Examples

Non-extended notation, using "token":

  foo: bar; title=Economy

Non-extended notation, using "quoted-string":

  foo: bar; title="US-$ rates"

Extended notation, using the unicode character U+00A3 (POUND SIGN):

  foo: bar; title*=iso-8859-1'en'%A3%20rates

Note: the Unicode pound sign character U+00A3 was encoded using ISO-8859-1 into the single octet A3, then percent-encoded. Also note that the space character was encoded as %20, as it is not contained in attr-char.

Extended notation, using the unicode characters U+00A3 (POUND SIGN) and U+20AC (EURO SIGN):

  foo: bar; title*=UTF-8''%c2%a3%20and%20%e2%82%ac%20rates

Note: the unicode pound sign character U+00A3 was encoded using UTF-8 into the octet sequence C2 A3, then percent-encoded. Likewise, the unicode euro sign character U+20AC was encoded into the octet sequence E2 82 AC, then percent-encoded. Also note that HEXDIG allows both lower-case and upper-case character, so recipients must understand both, and that the language information is optional, while the character set is not.

3.3. Language specification in Encoded Words

Section 5 of [RFC2231] extends the encoding defined in [RFC2047] to also support language specification in encoded words. Although the HTTP/1.1 specification does refer to RFC 2047 ([RFC2616], Section 2.2), it's not clear to which header field exactly it applies, and whether it is implemented in practice (see <http://tools.ietf.org/wg/httpbis/trac/ticket/111> for details).¶

Thus, the RFC 2231 profile defined by this specification does not include this feature.¶

4. Guidelines for Usage in HTTP Header Field Definitions

Specifications of HTTP header fields that use the extensions defined in Section 3.2 should clearly state that. A simple way to achieve this is to normatively reference this specification, and to include the ext-value production into the ABNF for that header field.¶

For instance:

  foo-header  = "foo" LWSP ":" LWSP token ";" LWSP title-param
  title-param = "title" LWSP "=" LWSP value
              / "title*" LWSP "=" LWSP ext-value
  ext-value   = <see RFCxxxx, Section 3.2>

[rfcno: Note to RFC Editor: in the figure above, please replace "xxxx" by the RFC number assigned to this specification.] ¶

4.1. When to Use the Extension

I when-ext-value (type: change, status: open)
julian.reschke@greenbytes.de	2010-02-18	There's no point in using ext-value when the language is unknown and no "special" characters are present.

Section 4.2 of [RFC2277] requires that protocol elements containing text are able to carry language information. Thus, the ext-value production should always be used when the parameter value is of textual nature.¶

I usascii-normative (type: change, status: closed)
julian.reschke@greenbytes.de	2010-02-20	The reference to USASCII needs to be normative.
	2010-02-20	Resolution:Done.
Associated changes in this document: 8.1, 8.1, 8.2, 8.2.

Furthermore, the extension should also be used whenever the parameter value needs to carry characters not present in the US-ASCII ([USASCII]) character set (note that it would be unacceptable to define a new parameter that would be restricted to a subset of the Unicode character set).¶

4.2. Error Handling

Header specifications that include parameters should also specify whether same-named parameters can occur multiple times. If repetitions are not allowed (and this is believed to be the common case), the specification should state whether regular or the extended syntax takes precedence. In the latter case, this could be used by producers to use both formats without breaking recipients that do not understand the syntax.¶

Example:

  foo: bar; title="EURO exchange rates";
            title*=utf-8''%e2%82%ac%20exchange%20rates

In this case, the sender provides an ASCII version of the title for legacy recipients, but also includes an internationalized version for recipients understanding this specification -- the latter obviously should prefer the new syntax over the old one.

4.3. Using Multiple Instances for Internationalization

It is expected that in many cases, internationalization of parameters in response headers is implemented using server driven content negotiation ([RFC2616], Section 12.1) using the Accept-Language header ([RFC2616], Section 14.4). However, the format described in this specification also allows using multiple instances providing multiple languages in a single header. Specifications that want to take advantage of this should clearly specify the expected processing by the recipient.¶

Example:

  foo: bar; title*=utf-8'en'Document%20Title;
            title*=utf-8'de'Titel%20des%20Dokuments

5. Security Considerations

I i18n-spoofing (type: change, status: open)
GK@ninebynine.org	2010-02-20	I note that the security considerations section says nothing about possible character "spoofing" - i.e. making a displayed prompt or value appear to be something other than it is. E.g. Non-ASCII characters have been used to set up exploits involving dodgy URIs that may appear to a user to be legitimate.

This document does not discuss security issues and is not believed to raise any security issues not already endemic in HTTP.¶

6. IANA Considerations

There are no IANA Considerations related to this specification.¶

7. Acknowledgements

Thanks to Martin Duerst and Frank Ellermann for help figuring out ABNF details, I ↓to Graham Klyne and Alexey Melnikov for general review,and to Benjamin Carlyle and Roar Lauritzsen for implementer's feedback.¶

8. References

8.1. Normative References

[ISO-8859-1]: International Organization for Standardization, “Information technology -- 8-bit single-byte coded graphic character sets -- Part 1: Latin alphabet No. 1”, ISO/IEC 8859-1:1998, 1998.
[RFC2119]: Bradner, S., “Key words for use in RFCs to Indicate Requirement Levels”, BCP 14, RFC 2119, March 1997.
[RFC2616]: Fielding, R., Gettys, J., Mogul, J., Frystyk, H., Masinter, L., Leach, P., and T. Berners-Lee, “Hypertext Transfer Protocol -- HTTP/1.1”, RFC 2616, June 1999.
I ↓ [RFC2978]: Freed, N. and J. Postel, “IANA Charset Registration Procedures”, BCP 19, RFC 2978, October 2000.
[RFC3629]: Yergeau, F., “UTF-8, a transformation format of ISO 10646”, RFC 3629, STD 63, November 2003.
I ↓ [RFC3986]: Berners-Lee, T., Fielding, R., and L. Masinter, “Uniform Resource Identifier (URI): Generic Syntax”, RFC 3986, STD 66, January 2005.
[RFC5234]: Crocker, D., Ed. and P. Overell, “Augmented BNF for Syntax Specifications: ABNF”, STD 68, RFC 5234, January 2008.
[RFC5646]: Phillips, A., Ed. and M. Davis, Ed., “Tags for Identifying Languages”, BCP 47, RFC 5646, September 2009.
↑ I ↓ [USASCII]: American National Standards Institute, “Coded Character Set -- 7-bit American Standard Code for Information Interchange”, ANSI X3.4, 1986.

8.2. Informative References

↑ I [RFC3986]: Berners-Lee, T., Fielding, R., and L. Masinter, “Uniform Resource Identifier (URI): Generic Syntax”, RFC 3986, STD 66, January 2005.
↑ I ↓ [USASCII]: American National Standards Institute, “Coded Character Set -- 7-bit American Standard Code for Information Interchange”, ANSI X3.4, 1986.
↑ I [RFC2978]: Freed, N. and J. Postel, “IANA Charset Registration Procedures”, BCP 19, RFC 2978, October 2000.
[RFC2045]: Freed, N. and N. Borenstein, “Multipurpose Internet Mail Extensions (MIME) Part One: Format of Internet Message Bodies”, RFC 2045, November 1996.
[RFC2047]: Moore, K., “MIME (Multipurpose Internet Mail Extensions) Part Three: Message Header Extensions for Non-ASCII Text”, RFC 2047, November 1996.
[RFC2231]: Freed, N. and K. Moore, “MIME Parameter Value and Encoded Word Extensions: Character Sets, Languages, and Continuations”, RFC 2231, November 1997.
[RFC2277]: Alvestrand, H., “IETF Policy on Character Sets and Languages”, BCP 18, RFC 2277, January 1998.
[RFC2388]: Masinter, L., “Returning Values from Forms: multipart/form-data”, RFC 2388, August 1998.

Appendix A. Document History and Future Plans (to be removed by RFC Editor before publication)

Problems with the internationalization of the HTTP Content-Disposition header field have been known for many years (see test cases at <http://greenbytes.de/tech/tc2231/>).¶

During IETF 72 (<http://tools.ietf.org/wg/httpbis/minutes?item=minutes72.html>), the HTTPbis Working Group shortly discussed how to deal with the underspecification of (1) Content-Disposition, and its (2) internationalization aspects. Back then, there was rough consensus in the room to move the definition into a separate draft.¶

This specification addresses problem (2), by defining a simple subset of the encoding format defined in RFC 2231. A separate specification, draft-reschke-rfc2183-in-http, is planned to address problem (1). Note that this approach was chosen because Content-Disposition is just an example for an HTTP header field using this kind of encoding. Another example is the currently proposed Link header field (draft-nottingham-http-link-header).¶

This document is planned to be published on the IETF Standards Track, so that other standards-track level documents can depend on it, such as the new specification of Content-Disposition, or potentially future revisions of the HTTP Link Header specification.¶

Also note that this document specifies a proper subset of the extensions defined in RFC 2231, but does not normatively refer to it. Thus, RFC 2231 can be revised separately, should the email community decide to.¶

Appendix B. Change Log (to be removed by RFC Editor before publication)

B.1. Since draft-reschke-rfc2231-in-http-00

Use RFC5234-style ABNF, closer to the one used in RFC 2231.¶

Make RFC 2231 dependency informative, so this specification can evolve independently.¶

Explain the ABNF in prose.¶

I edit (type: edit, status: open)
julian.reschke@greenbytes.de	2009-04-17	Umbrella issue for editorial fixes/enhancements.
Associated changes in this document: 7, B.