Structured Headers for HTTP

Abstract

This document describes a set of data types and algorithms associated with them that are intended to make it easier and safer to define and handle HTTP header fields. It is intended for use by new specifications of HTTP header fields as well as revisions of existing header field specifications when doing so does not cause interoperability issues.¶

Status of this Memo

This Internet-Draft is submitted in full conformance with the provisions of BCP 78 and BCP 79.¶

Internet-Drafts are working documents of the Internet Engineering Task Force (IETF). Note that other groups may also distribute working documents as Internet-Drafts. The list of current Internet-Drafts is at https://datatracker.ietf.org/drafts/current/.¶

Internet-Drafts are draft documents valid for a maximum of six months and may be updated, replaced, or obsoleted by other documents at any time. It is inappropriate to use Internet-Drafts as reference material or to cite them other than as “work in progress”.¶

This Internet-Draft will expire on April 26, 2019.¶

Copyright Notice

This document is subject to BCP 78 and the IETF Trust's Legal Provisions Relating to IETF Documents (https://trustee.ietf.org/license-info) in effect on the date of publication of this document. Please review these documents carefully, as they describe your rights and restrictions with respect to this document. Code Components extracted from this document must include Simplified BSD License text as described in Section 4.e of the Trust Legal Provisions and are provided without warranty as described in the Simplified BSD License.¶

1. Introduction

Specifying the syntax of new HTTP header fields is an onerous task; even with the guidance in [RFC7231], Section 8.3.1, there are many decisions – and pitfalls – for a prospective HTTP header field author.¶

Once a header field is defined, bespoke parsers and serialisers often need to be written, because each header has slightly different handling of what looks like common syntax.¶

This document introduces a set of common data structures for use in HTTP header field values to address these problems. In particular, it defines a generic, abstract model for header field values, along with a concrete serialisation for expressing that model in HTTP/1 [RFC7230] header fields.¶

HTTP headers that are defined as “Structured Headers” use the types defined in this specification to define their syntax and basic handling rules, thereby simplifying both their definition by specification writers and handling by implementations.¶

Additionally, future versions of HTTP can define alternative serialisations of the abstract model of these structures, allowing headers that use it to be transmitted more efficiently without being redefined.¶

Note that it is not a goal of this document to redefine the syntax of existing HTTP headers; the mechanisms described herein are only intended to be used with headers that explicitly opt into them.¶

To specify a header field that is a Structured Header, see Section 2.¶

Section 3 defines a number of abstract data types that can be used in Structured Headers.¶

Those abstract types can be serialised into and parsed from textual headers – such as those used in HTTP/1 – using the algorithms described in Section 4.¶

1.1. Notational Conventions

The key words “MUST”, “MUST NOT”, “REQUIRED”, “SHALL”, “SHALL NOT”, “SHOULD”, “SHOULD NOT”, “RECOMMENDED”, “NOT RECOMMENDED”, “MAY”, and “OPTIONAL” in this document are to be interpreted as described in BCP 14 [RFC2119] [RFC8174] when, and only when, they appear in all capitals, as shown here.¶

This document uses the Augmented Backus-Naur Form (ABNF) notation of [RFC5234], including the VCHAR, SP, DIGIT, ALPHA and DQUOTE rules from that document. It also includes the OWS rule from [RFC7230].¶

This document uses algorithms to specify parsing and serialisation behaviours, and ABNF to illustrate expected syntax in HTTP/1-style header fields.¶

For parsing from HTTP/1 header fields, implementations MUST follow the algorithms, but MAY vary in implementation so as the behaviours are indistinguishable from specified behaviour. If there is disagreement between the parsing algorithms and ABNF, the specified algorithms take precedence. In some places, the algorithms are “greedy” with whitespace, but this should not affect conformance.¶

For serialisation to HTTP/1 header fields, the ABNF illustrates the range of acceptable wire representations with as much fidelity as possible, and the algorithms define the recommended way to produce them. Implementations MAY vary from the specified behaviour so long as the output still matches the ABNF.¶

2. Defining New Structured Headers

To define a HTTP header as a structured header, its specification needs to:¶

Reference this specification. Recipients and generators of the header need to know that the requirements of this document are in effect.
Specify the header field’s allowed syntax for values, in terms of the types described in Section 3, along with their associated semantics. Syntax definitions are encouraged to use the ABNF rules beginning with “sh-“ defined in this specification.
Specify any additional constraints upon the syntax of the structured used, as well as the consequences when those constraints are violated. When Structured Headers parsing fails, the header is discarded (see Section 4.2); in most situations, header-specific constraints should do likewise.

Note that a header field definition cannot relax the requirements of a structure or its processing because doing so would preclude handling by generic software; they can only add additional constraints.¶

For example:¶

# Foo-Example Header

The Foo-Example HTTP header field conveys information about how
much Foo the message has.

Foo-Example is a Structured Header [RFCxxxx]. Its value MUST be a
dictionary ([RFCxxxx], Section Y.Y). Its ABNF is:

  Foo-Example = sh-dictionary

The dictionary MUST contain:

* Exactly one member whose key is "foo", and whose value is an
  integer ([RFCxxxx], Section Y.Y), indicating the number of foos
  in the message.
* Exactly one member whose key is "barUrls", and whose value is a
  string ([RFCxxxx], Section Y.Y), conveying the Bar URLs for the
  message. See below for processing requirements.

If the parsed header field does not contain both, it MUST be
ignored.

"foo" MUST be between 0 and 10, inclusive; other values MUST cause
the header to be ignored.

"barUrls" contains a space-separated list of URI-references
([RFC3986], Section 4.1):

   barURLs = URI-reference *( 1*SP URI-reference )

If a member of barURLs is not a valid URI-reference, it MUST cause
that value to be ignored.

If a member of barURLs is a relative reference ([RFC3986],
Section 4.2), it MUST be resolved ([RFC3986], Section 5) before
being used.

This specification defines minimums for the length or number of various structures supported by Structured Headers implementations. It does not specify maximum sizes in most cases, but header authors should be aware that HTTP implementations do impose various limits on the size of individual header fields, the total number of fields, and/or the size of the entire header block.¶

3. Structured Header Data Types

This section defines the abstract value types that can be composed into Structured Headers. The ABNF provided represents the on-wire format in HTTP/1.¶

3.1. Dictionaries

Dictionaries are ordered maps of key-value pairs, where the keys are identifiers (Section 3.8) and the values are items (Section 3.4). There can be one or more members, and keys are required to be unique.¶

Implementations MUST provide access to dictionaries both by index and by key. Specifications MAY use either means of accessing the members.¶

The ABNF for dictionaries in HTTP/1 headers is:¶

sh-dictionary  = dict-member *( OWS "," OWS dict-member )
dict-member    = member-name "=" member-value
member-name    = sh-identifier
member-value   = sh-item

In HTTP/1, keys and values are separated by “=” (without whitespace), and key/value pairs are separated by a comma with optional whitespace. For example:¶

Example-DictHeader: en="Applepie", da=*w4ZibGV0w6ZydGU=*

Typically, a header field specification will define the semantics of individual keys, as well as whether their presence is required or optional. Recipients MUST ignore keys that are undefined or unknown, unless the header field’s specification specifically disallows them.¶

Parsers MUST support dictionaries containing at least 1024 key/value pairs.¶

3.2. Lists

Lists are arrays of items (Section 3.4) with one or more members.¶

The ABNF for lists in HTTP/1 headers is:¶

sh-list     = list-member *( OWS "," OWS list-member )
list-member = sh-item

In HTTP/1, each member is separated by a comma and optional whitespace. For example, a header field whose value is defined as a list of strings could look like:¶

Example-StrListHeader: "foo", "bar", "It was the best of times."

Header specifications can constrain the types of individual values if necessary.¶

Parsers MUST support lists containing at least 1024 members.¶

3.3. Parameterised Lists

Parameterised Lists are arrays of a parameterised identifiers.¶

A parameterised identifier is an identifier (Section 3.8) with an optional set of parameters, each parameter having an identifier and an optional value that is an item (Section 3.4). Ordering between parameters is not significant, and duplicate parameters MUST cause parsing to fail.¶

The ABNF for parameterised lists in HTTP/1 headers is:¶

sh-param-list = param-id *( OWS "," OWS param-id )
param-id      = sh-identifier *parameter
parameter     = OWS ";" OWS param-name [ "=" param-value ]
param-name    = sh-identifier
param-value   = sh-item

In HTTP/1, each param-id is separated by a comma and optional whitespace (as in Lists), and the parameters are separated by semicolons. For example:¶

Example-ParamListHeader: abc_123;a=1;b=2; cdef_456, ghi;q="9";r="w"

Parsers MUST support parameterised lists containing at least 1024 members, and support members with at least 256 parameters.¶

3.4. Items

An item is can be a integer (Section 3.5), float (Section 3.6), string (Section 3.7), identifier (Section 3.8), byte sequence (Section 3.9), or Boolean (Section 3.10).¶

The ABNF for items in HTTP/1 headers is:¶

sh-item = sh-integer / sh-float / sh-string / sh-identifier / sh-binary
          / sh-boolean

3.5. Integers

Integers have a range of −9,223,372,036,854,775,808 to 9,223,372,036,854,775,807 inclusive (i.e., a 64-bit signed integer).¶

The ABNF for integers in HTTP/1 headers is:¶

sh-integer = ["-"] 1*19DIGIT

For example:¶

Example-IntegerHeader: 42

3.6. Floats

Floats are integers with a fractional part, that can be stored as IEEE 754 double precision numbers (binary64) ([IEEE754]).¶

The ABNF for floats in HTTP/1 headers is:¶

sh-float    = ["-"] (
             DIGIT "." 1*14DIGIT /
            2DIGIT "." 1*13DIGIT /
            3DIGIT "." 1*12DIGIT /
            4DIGIT "." 1*11DIGIT /
            5DIGIT "." 1*10DIGIT /
            6DIGIT "." 1*9DIGIT /
            7DIGIT "." 1*8DIGIT /
            8DIGIT "." 1*7DIGIT /
            9DIGIT "." 1*6DIGIT /
           10DIGIT "." 1*5DIGIT /
           11DIGIT "." 1*4DIGIT /
           12DIGIT "." 1*3DIGIT /
           13DIGIT "." 1*2DIGIT /
           14DIGIT "." 1DIGIT )

For example, a header whose value is defined as a float could look like:¶

Example-FloatHeader: 4.5

3.7. Strings

Strings are zero or more printable ASCII [RFC0020] characters (i.e., the range 0x20 to 0x7E). Note that this excludes tabs, newlines, carriage returns, etc.¶

The ABNF for strings in HTTP/1 headers is:¶

sh-string = DQUOTE *(chr) DQUOTE
chr       = unescaped / escaped
unescaped = %x20-21 / %x23-5B / %x5D-7E
escaped   = "\" ( DQUOTE / "\" )

In HTTP/1 headers, strings are delimited with double quotes, using a backslash (“\”) to escape double quotes and backslashes. For example:¶

Example-StringHeader: "hello world"

Note that strings only use DQUOTE as a delimiter; single quotes do not delimit strings. Furthermore, only DQUOTE and “\” can be escaped; other sequences MUST cause parsing to fail.¶

Unicode is not directly supported in this document, because it causes a number of interoperability issues, and – with few exceptions – header values do not require it.¶

When it is necessary for a field value to convey non-ASCII string content, a byte sequence (Section 3.9) SHOULD be specified, along with a character encoding (preferably UTF-8).¶

Parsers MUST support strings with at least 1024 characters.¶

3.8. Identifiers

Identifiers are short textual identifiers; their abstract model is identical to their expression in the textual HTTP serialisation. Parsers MUST support identifiers with at least 64 characters.¶

The ABNF for identifiers in HTTP/1 headers is:¶

sh-identifier = lcalpha *( lcalpha / DIGIT / "_" / "-"/ "*" / "/" )
lcalpha       = %x61-7A ; a-z

Note that identifiers can only contain lowercase letters.¶

3.9. Byte Sequences

Byte sequences can be conveyed in Structured Headers.¶

The ABNF for a byte sequence in HTTP/1 headers is:¶

sh-binary = "*" *(base64) "*"
base64    = ALPHA / DIGIT / "+" / "/" / "="

In HTTP/1 headers, a byte sequence is delimited with asterisks and encoded using base64 ([RFC4648], Section 4). For example:¶

Example-BinaryHdr: *cHJldGVuZCB0aGlzIGlzIGJpbmFyeSBjb250ZW50Lg==*

Parsers MUST support byte sequences with at least 16384 octets after decoding.¶

3.10. Booleans

Boolean values can be conveyed in Structured Headers.¶

The ABNF for a Boolean in HTTP/1 headers is:¶

sh-boolean = "!" boolean
boolean    = "T" / "F"

In HTTP/1 headers, a byte sequence is delimited with a “!” character. For example:¶

Example-BoolHdr: !T

4. Structured Headers in HTTP/1

This section defines how to serialise and parse Structured Headers in HTTP/1 textual header fields, and protocols compatible with them (e.g., in HTTP/2 [RFC7540] before HPACK [RFC7541] is applied).¶

4.1. Serialising Structured Headers into HTTP/1

Given a structured defined in this specification:¶

If the structure is a dictionary, return the result of Serialising a Dictionary {#ser-dictionary}.
If the structure is a list, return the result of Serialising a List {#ser-list}.
If the structure is a parameterised list, return the result of Serialising a Parameterised List {#ser-param-list}.
If the structure is an item, return the result of Serialising an Item {#ser-item}.
Otherwise, fail serialisation.

4.1.1. Serialising a Dictionary

Given a dictionary as input:¶

Let output be an empty string.
For each member mem of input:
1. Let name be the result of applying Serialising an Identifier Section 4.1.8 to mem’s member-name.
2. Append name to output.
3. Append “=” to output.
4. Let value be the result of applying Serialising an Item Section 4.1.4 to mem’s member-value.
5. Append value to output.
6. If more members remain in input:
  1. Append a COMMA to output.
  2. Append a single WS to output.
Return output.

4.1.2. Serialising a List

Given a list as input:¶

Let output be an empty string.
For each member mem of input:
1. Let value be the result of applying Serialising an Item Section 4.1.4 to mem.
2. Append value to output.
3. If more members remain in input:
  1. Append a COMMA to output.
  2. Append a single WS to output.
Return output.

4.1.3. Serialising a Parameterised List

Given a parameterised list as input:¶

Let output be an empty string.
For each member mem of input:
1. Let id be the result of applying Serialising an Identifier Section 4.1.8 to mem’s identifier.
2. Append id to output.
3. For each parameter in mem’s parameters:
  1. Append “;” to output.
  2. Let name be the result of applying Serialising an Identifier Section 4.1.8 to parameter’s param-name.
  3. Append name to output.
  4. If parameter has a param-value:
    1. Let value be the result of applying Serialising an Item Section 4.1.4 to parameter’s param-value.
    2. Append “=” to output.
    3. Append value to output.
4. If more members remain in input:
  1. Append a COMMA to output.
  2. Append a single WS to output.
Return output.

4.1.4. Serialising an Item

Given an item as input:¶

If input is a type other than an integer, float, string, identifier, byte sequence, or Boolean, fail serialisation.
If input is an integer, return the result of applying Serialising an Integer Section 4.1.5 to input.
If input is a float, return the result of applying Serialising a Float Section 4.1.6 to input.
If input is a string, return the result of applying Serialising a String Section 4.1.7 to input.
If input is an identifier, return the result of Serialising an Identifier {#ser-identifier}.
If input is a Boolean, return the result of applying Serialising a Boolean Section 4.1.10 to input.
Otherwise, return the result of applying Serialising a Byte Sequence Section 4.1.9 to input.

4.1.5. Serialising an Integer

Given an integer as input:¶

If input is not an integer in the range of −9,223,372,036,854,775,808 to 9,223,372,036,854,775,807 inclusive, fail serialisation.
Let output be an empty string.
If input is less than (but not equal to) 0, append “-“ to output.
Append input’s numeric value represented in base 10 using only decimal digits to output.
Return output.

4.1.6. Serialising a Float

Given a float as input:¶

If input is not a IEEE 754 double precision number, fail serialisation.
Let output be an empty string.
If input is less than (but not equal to) 0, append “-“ to output.
Append input’s integer component represented in base 10 using only decimal digits to output; if it is zero, append “0”.
Append “.” to output.
Append input’s decimal component represented in base 10 using only decimal digits to output; if it is zero, append “0”.
Return output.

4.1.7. Serialising a String

Given a string as input:¶

If input is not a sequence of characters, or contains characters outside the range allowed by VCHAR or SP, fail serialisation.
Let output be an empty string.
Append DQUOTE to output.
For each character char in input:
1. If char is “\” or DQUOTE:
  1. Append “\” to output.
2. Append char to output, using ASCII encoding [RFC0020].
Append DQUOTE to output.
Return output.

4.1.8. Serialising an Identifier

Given an identifier as input:¶

If input is not a sequence of characters, or contains characters not allowed in Section 3.8, fail serialisation.
Let output be an empty string.
Append input to output, using ASCII encoding [RFC0020].
Return output.

4.1.9. Serialising a Byte Sequence

Given a byte sequence as input:¶

If input is not a sequence of bytes, fail serialisation.
Let output be an empty string.
Append “*” to output.
Append the result of base64-encoding input as per [RFC4648], Section 4, taking account of the requirements below.
Append “*” to output.
Return output.

The encoded data is required to be padded with “=”, as per [RFC4648], Section 3.2.¶

Likewise, encoded data SHOULD have pad bits set to zero, as per [RFC4648], Section 3.5, unless it is not possible to do so due to implementation constraints.¶

4.1.10. Serialising a Boolean

Given a Boolean as input:¶

If input is not a boolean, fail serialisation.
Let output be an empty string.
Append “!” to output.
If input is true, append “T” to output.
If input is false, append “F” to output.
Return output.

4.2. Parsing HTTP/1 Header Fields into Structured Headers

When a receiving implementation parses textual HTTP header fields (e.g., in HTTP/1 or HTTP/2) that are known to be Structured Headers, it is important that care be taken, as there are a number of edge cases that can cause interoperability or even security problems. This section specifies the algorithm for doing so.¶

Given an ASCII string input_string that represents the chosen header’s field-value, and header_type, one of “dictionary”, “list”, “param-list”, or “item”, return the parsed header value.¶

Discard any leading OWS from input_string.
If header_type is “dictionary”, let output be the result of Parsing a Dictionary from Text (Section 4.2.1).
If header_type is “list”, let output be the result of Parsing a List from Text (Section 4.2.2).
If header_type is “param-list”, let output be the result of Parsing a Parameterised List from Text (Section 4.2.3).
Otherwise, let output be the result of Parsing an Item from Text (Section 4.2.5).
Discard any leading OWS from input_string.
If input_string is not empty, fail parsing.
Otherwise, return output.

When generating input_string, parsers MUST combine all instances of the target header field into one comma-separated field-value, as per [RFC7230], Section 3.2.2; this assures that the header is processed correctly.¶

For Lists, Parameterised Lists and Dictionaries, this has the effect of correctly concatenating all instances of the header field.¶

Strings split across multiple header instances will have unpredictable results, because comma(s) and whitespace inserted upon combination will become part of the string output by the parser. Since concatenation might be done by an upstream intermediary, the results are not under the control of the serialiser or the parser.¶

Integers, Floats and Byte Sequences cannot be split across multiple headers because the inserted commas will cause parsing to fail.¶

If parsing fails – including when calling another algorithm – the entire header field’s value MUST be discarded. This is intentionally strict, to improve interoperability and safety, and specifications referencing this document cannot loosen this requirement.¶

Note that this has the effect of discarding any header field with non-ASCII characters in input_string.¶

4.2.1. Parsing a Dictionary from Text

Given an ASCII string input_string, return an ordered map of (identifier, item). input_string is modified to remove the parsed value.¶

Let dictionary be an empty, ordered map.
While input_string is not empty:
1. Let this_key be the result of running Parse Identifier from Text (Section 4.2.8) with input_string.
2. If dictionary already contains this_key, fail parsing.
3. Consume the first character of input_string; if it is not “=”, fail parsing.
4. Let this_value be the result of running Parse Item from Text (Section 4.2.5) with input_string.
5. Add key this_key with value this_value to dictionary.
6. Discard any leading OWS from input_string.
7. If input_string is empty, return dictionary.
8. Consume the first character of input_string; if it is not COMMA, fail parsing.
9. Discard any leading OWS from input_string.
10. If input_string is empty, fail parsing.
No structured data has been found; fail parsing.

4.2.2. Parsing a List from Text

Given an ASCII string input_string, return a list of items. input_string is modified to remove the parsed value.¶

Let items be an empty array.
While input_string is not empty:
1. Let item be the result of running Parse Item from Text (Section 4.2.5) with input_string.
2. Append item to items.
3. Discard any leading OWS from input_string.
4. If input_string is empty, return items.
5. Consume the first character of input_string; if it is not COMMA, fail parsing.
6. Discard any leading OWS from input_string.
7. If input_string is empty, fail parsing.
No structured data has been found; fail parsing.

4.2.3. Parsing a Parameterised List from Text

Given an ASCII string input_string, return a list of parameterised identifiers. input_string is modified to remove the parsed value.¶

Let items be an empty array.
While input_string is not empty:
1. Let item be the result of running Parse Parameterised Identifier from Text (Section 4.2.4) with input_string.
2. Append item to items.
3. Discard any leading OWS from input_string.
4. If input_string is empty, return items.
5. Consume the first character of input_string; if it is not COMMA, fail parsing.
6. Discard any leading OWS from input_string.
7. If input_string is empty, fail parsing.
No structured data has been found; fail parsing.

4.2.4. Parsing a Parameterised Identifier from Text

Given an ASCII string input_string, return an identifier with an unordered map of parameters. input_string is modified to remove the parsed value.¶

Let primary_identifier be the result of Parsing an Identifier from Text (Section 4.2.8) from input_string.
Let parameters be an empty, unordered map.
In a loop:
1. If the first character of input_string is not “;”, exit the loop.
2. Consume a “;” character from the beginning of input_string.
3. Discard any leading OWS from input_string.
4. let param_name be the result of Parsing an Identifier from Text (Section 4.2.8) from input_string.
5. If param_name is already present in parameters, fail parsing.
6. Let param_value be a null value.
7. If the first character of input_string is “=”:
  1. Consume the “=” character at the beginning of input_string.
  2. Let param_value be the result of Parsing an Item from Text (Section 4.2.5) from input_string.
8. Insert (param_name, param_value) into parameters.
Return the tuple (primary_identifier, parameters).

4.2.5. Parsing an Item from Text

Given an ASCII string input_string, return an item. input_string is modified to remove the parsed value.¶

Discard any leading OWS from input_string.
If the first character of input_string is a “-“ or a DIGIT, process input_string as a number (Section 4.2.6) and return the result.
If the first character of input_string is a DQUOTE, process input_string as a string (Section 4.2.7) and return the result.
If the first character of input_string is “*”, process input_string as a byte sequence (Section 4.2.9) and return the result.
If the first character of input_string is “!”, process input_string as a Boolean (Section 4.2.10) and return the result.
If the first character of input_string is a lcalpha, process input_string as an identifier (Section 4.2.8) and return the result.
Otherwise, fail parsing.

4.2.6. Parsing a Number from Text

NOTE: This algorithm parses both Integers Section 3.5 and Floats Section 3.6, and returns the corresponding structure.¶

Let type be “integer”.
Let sign be 1.
Let input_number be an empty string.
If the first character of input_string is “-“, remove it from input_string and set sign to -1.
If input_string is empty, fail parsing.
If the first character of input_string is not a DIGIT, fail parsing.
While input_string is not empty:
1. Let char be the result of removing the first character of input_string.
2. If char is a DIGIT, append it to input_number.
3. Else, if type is “integer” and char is “.”, append char to input_number and set type to “float”.
4. Otherwise, prepend char to input_string, and exit the loop.
5. If type is “integer” and input_number contains more than 19 characters, fail parsing.
6. If type is “float” and input_number contains more than 16 characters, fail parsing.
If type is “integer”:
1. Parse input_number as an integer and let output_number be the product of the result and sign.
2. If output_number is outside the range defined in Section 3.5, fail parsing.
Otherwise:
1. If the final character of input_number is “.”, fail parsing.
2. Parse input_number as a float and let output_number be the product of the result and sign.
Return output_number.

4.2.7. Parsing a String from Text

Given an ASCII string input_string, return an unquoted string. input_string is modified to remove the parsed value.¶

Let output_string be an empty string.
If the first character of input_string is not DQUOTE, fail parsing.
Discard the first character of input_string.
While input_string is not empty:
1. Let char be the result of removing the first character of input_string.
2. If char is a backslash (“\”):
  1. If input_string is now empty, fail parsing.
  2. Else:
    1. Let next_char be the result of removing the first character of input_string.
    2. If next_char is not DQUOTE or “\”, fail parsing.
    3. Append next_char to output_string.
3. Else, if char is DQUOTE, return output_string.
4. Else, if char is in the range %x00-1f or %x7f (i.e., is not in VCHAR or SP), fail parsing.
5. Else, append char to output_string.
Reached the end of input_string without finding a closing DQUOTE; fail parsing.

4.2.8. Parsing an Identifier from Text

Given an ASCII string input_string, return an identifier. input_string is modified to remove the parsed value.¶

If the first character of input_string is not lcalpha, fail parsing.
Let output_string be an empty string.
While input_string is not empty:
1. Let char be the result of removing the first character of input_string.
2. If char is not one of lcalpha, DIGIT, “_”, “-“, “*” or “/”:
  1. Prepend char to input_string.
  2. Return output_string.
3. Append char to output_string.
Return output_string.

4.2.9. Parsing a Byte Sequence from Text

Given an ASCII string input_string, return a byte sequence. input_string is modified to remove the parsed value.¶

If the first character of input_string is not “*”, fail parsing.
Discard the first character of input_string.
Let b64_content be the result of removing content of input_string up to but not including the first instance of the character “*”. If there is not a “*” character before the end of input_string, fail parsing.
Consume the “*” character at the beginning of input_string.
If b64_content contains a character not included in ALPHA, DIGIT, “+”, “/” and “=”, fail parsing.
Let binary_content be the result of Base 64 Decoding [RFC4648] b64_content, synthesising padding if necessary (note the requirements about recipient behaviour below).
Return binary_content.

Because some implementations of base64 do not allow reject of encoded data that is not properly “=” padded (see [RFC4648], Section 3.2), parsers SHOULD NOT fail when it is not present, unless they cannot be configured to do so.¶

Because some implementations of base64 do not allow rejection of encoded data that has non-zero pad bits (see [RFC4648], Section 3.5), parsers SHOULD NOT fail when it is present, unless they cannot be configured to do so.¶

This specification does not relax the requirements in [RFC4648], Section 3.1 and 3.3; therefore, parsers MUST fail on characters outside the base64 alphabet, and on line feeds in encoded data.¶

4.2.10. Parsing a Boolean from Text

Given an ASCII string input_string, return a Boolean. input_string is modified to remove the parsed value.¶

If the first character of input_string is not “!”, fail parsing.
Discard the first character of input_string.
If the first character of input_string case-sensitively matches “T”, discard the first character, and return true.
If the first character of input_string case-sensitively matches “F”, discard the first character, and return false.
No value has matched; fail parsing.

5. IANA Considerations

This draft has no actions for IANA.¶

6. Security Considerations

The size of most types defined by Structured Headers is not limited; as a result, extremely large header fields could be an attack vector (e.g., for resource consumption). Most HTTP implementations limit the sizes of size of individual header fields as well as the overall header block size to mitigate such attacks.¶

It is possible for parties with the ability to inject new HTTP header fields to change the meaning of a Structured Header. In some circumstances, this will cause parsing to fail, but it is not possible to reliably fail in all such circumstances.¶

Appendix A. Frequently Asked Questions

A.1. Why not JSON?

Earlier proposals for structured headers were based upon JSON [RFC8259]. However, constraining its use to make it suitable for HTTP header fields required senders and recipients to implement specific additional handling.¶

For example, JSON has specification issues around large numbers and objects with duplicate members. Although advice for avoiding these issues is available (e.g., [RFC7493]), it cannot be relied upon.¶

Likewise, JSON strings are by default Unicode strings, which have a number of potential interoperability issues (e.g., in comparison). Although implementers can be advised to avoid non-ASCII content where unnecessary, this is difficult to enforce.¶

Another example is JSON’s ability to nest content to arbitrary depths. Since the resulting memory commitment might be unsuitable (e.g., in embedded and other limited server deployments), it’s necessary to limit it in some fashion; however, existing JSON implementations have no such limits, and even if a limit is specified, it’s likely that some header field definition will find a need to violate it.¶

Because of JSON’s broad adoption and implementation, it is difficult to impose such additional constraints across all implementations; some deployments would fail to enforce them, thereby harming interoperability.¶

Since a major goal for Structured Headers is to improve interoperability and simplify implementation, these concerns led to a format that requires a dedicated parser and serialiser.¶

Additionally, there were widely shared feelings that JSON doesn’t “look right” in HTTP headers.¶

A.2. Structured Headers don’t “fit” my data.

Structured headers intentionally limits the complexity of data structures, to assure that it can be processed in a performant manner with little overhead. This means that work is necessary to fit some data types into them.¶

Sometimes, this can be achieved by creating limited substructures in values, and/or using more than one header. For example, consider:¶

Example-Thing: name="Widget", cost=89.2, descriptions="foo bar"
Example-Description: foo; url="https://example.net"; context=123,
                     bar; url="https://example.org"; context=456

Since the description contains a list of key/value pairs, we use a Parameterised List to represent them, with the identifier for each item in the list used to identify it in the “descriptions” member of the Example-Thing header.¶

When specifying more than one header, it’s important to remember to describe what a processor’s behaviour should be when one of the headers is missing.¶

If you need to fit arbitrarily complex data into a header, Structured Headers is probably a poor fit for your use case.¶

Appendix B. Changes

RFC Editor: Please remove this section before publication. ¶

B.1. Since draft-ietf-httpbis-header-structure-07 📄 🔍

Make Dictionaries ordered mappings (#659).
Changed “binary content” to “byte sequence” to align with Infra specification (#671).
Changed “mapping” to “map” for #671.
Don’t fail if byte sequences aren’t “=” padded (#658).
Add Booleans (#683).
Allow identifiers in items again (#629).
Disallowed whitespace before items (#703).
Explain the consequences of splitting a string across multiple headers (#686).